Budowa sygnalizacji świetlnej

Układ, który zbudujemy oraz oprogramujemy będzie realizować następujący scenariusz:

1. Pojazdy mają zielone światło. Pieszy, który stoi na czerwonym świetle, naciska przycisk, aby zmienić je na zielone.

2. Światło dla pojazdów zmienia się na żółte. Kierowcy są w ten sposób informowani, że należy się zatrzymać, ponieważ za chwilę światło będzie czerwone.

3. Światło dla pojazdów zmienia się na czerwone; piesi mają światło zielone.

4. Światło zielone dla pieszych zaczyna migać. Pojazdy nadal mają czerwone światło.

5. Światło dla pieszych zmienia się na czerwone. Z kolei kierowcy widzą palące się równocześnie światła czerwone i żółte.

Po osiągnięciu punktu 5. wracamy do stanu sygnalizacji opisanego w punkcie 1.

Elementy potrzebne do budowy

• płytka Arduino Uno

• płytka stykowa

• kabel USB typu A‑B

• czerwone diody LED (2 sztuki)

• żółta dioda LED

• zielone diody LED (2 sztuki)

• włącznik zwierny

• rezystory 220 Ωomega (5 sztuk)

• rezystor 10 kΩomega

• przewody i zworki połączeniowe

Zacznijmy od umieszczenia na płytce prototypowej trzech diod LED symbolizujących światła dla samochodów oraz dwóch odpowiadających światłom dla pieszych. Załóżmy, że diody, które będą stanowiły sygnalizator dla pojazdów, podłączymy do pinów 8., 9. i 10., natomiast diody dla pieszych podepniemy do pinów 6. i 7. Oczywiście możesz wybrać inne piny, jednak musisz zmodyfikować wówczas kod szkicu, który przedstawimy niżej.

Połączmy diody zgodnie ze schematem.

1. Łączymy masę (GND) z płytki Arduino z ujemną szyną płytki stykowej.

R1b24VKoSYgwE

Zdjęcie przedstawia połączenie masy (GND) z płytki Arduino z ujemną szyną płytki stykowej.

2. Łączymy piny 8., 9. i 10. z płytką stykową. Numery wierszy na płytce prototypowej nie mają znaczenia (możesz wybrać inne niż pokazano na zdjęciu). Warto natomiast używać kolorowych przewodów – na początku pracy z płytką Arduino bardzo ułatwia to konstruowanie i oprogramowywanie układów.

RKOWeU7rSoArc

Zdjęcie przedstawia połączenia pinów 8., 9. i 10. z płytką stykową. Każdy z przewodów jest innego koloru.

3. Wpinamy rezystory 220 Ωomega. Jedną nóżkę każdego z nich umieszczamy w szynie danych, do której podłączyliśmy już przewód, a drugą wpinamy do drugiej szyny danych.

RJPMoVRsL4ITz

Zdjęcie przedstawia moduł Arduino oraz płytkę stykową połączone podpiętymi przewodami. Na zdjęciu widoczne są także wpięte rezystory 220 Ω omega. Jedną nóżkę każdego z nich umieszczona jest w szynie danych, do której podłączone są przewody, a druga wpięta jest do drugiej szyny danych.

4. Wpinamy do płytki stykowej diody LED. Pamiętajmy, aby anoda znajdowała się od strony rezystora, a katoda miała kontakt elektryczny z szyną masy.

RmaYVIoaqmcL7

Zdjęcie przedstawia moduł Arduino z płytką stykową połączone podpiętymi przewodami. Na zdjęciu znajdują się także wpięte rezystory oraz wpięte do płytki stykowej trzy diody LED: zielona, żółta i czerwona symulujące światła dla pojazdów. Anoda znajduje się od strony rezystora, a katoda ma kontakt elektryczny z szyną masy.

5. Część układu symulująca światła dla pojazdów jest gotowa. Pora na światła dla pieszych. Łączymy przewodami pin 6. i 7. z płytką stykową.

RHmmHXdqZejaF

Zdjęcie przedstawia moduł Arduino z płytką stykową połączone podpiętymi przewodami. Na zdjęciu znajdują się także wpięte rezystory oraz wpięte do płytki stykowej diody LED: zielona, żółta i czerwona symulujące światła dla pojazdów. Przewodami połączono pin 6. i 7. z płytką stykową.

6. Wpinamy do płytki stykowej rezystory 220 Ωomega oraz dwie diody LED. Postępujemy tak samo jak w poprzednich punktach.

R1QEXpYWjp8Ph

Zdjęcie przedstawia moduł Arduino z płytką stykową połączone podpiętymi przewodami. Na zdjęciu znajdują się pięć wpiętych rezystorów 220 Ω omega oraz wpięte do płytki stykowej diody LED: zielona, żółta i czerwona symulujące światła dla pojazdów, następnie dalej zielona i czerwona symulujące światła dla pieszych. Przewodami połączono piny z płytką stykową.

Sygnalizatory są podłączone. Brakuje jeszcze jednego elementu – przycisku, dzięki któremu piesi będą mogli włączać zielone światło. Zastosujemy włącznik chwilowywłącznik chwilowywłącznik chwilowy, zwany również przyciskiem RESET.

RrYNZTQOnorMF

Zdjęcie przedstawia mikrowłącznik arduino, inaczej włącznik chwilowy lub przyciskiem RESET, składający się z przycisku, sześciennej głównej części i czterech styków. Wszystkie cztery styki są ponumerowane cyframi od 1 do 4.

Naciśnięcie przycisku chwilowego, powoduje zwarcie styków 2–3 oraz 1–4 i przepływ prądu. Styki 1–2 oraz 3–4 są natomiast zawsze zwarte. Możesz jednak spotkać się również z przyciskiem rozwiernym – w jego przypadku styki są zawsze zwarte, a naciśnięcie powoduje ich rozwarcie.

Narysujmy na schemacie przycisk, który posłuży do sterowania światłami. Zwróć uwagę na linię reprezentującą przewód łączący wyprowadzenie napięcia 5 V z pinem 2. W miejscach, w których linia ta przecina się z innymi liniami, pojawia się zaokrąglenie. Nie oznacza to, że zastosowaliśmy specjalny przewód albo że go wygięliśmy. Jest to po prostu informacja, że między przecinającymi się na schemacie liniami nie ma kontaktu elektrycznego.

7. Łączymy pin 2. z płytką stykową – styk przewodu wkładamy w otwór szyny danych.

8. Podłączamy zasilanie do tej samej kolumny, do której jest podpięty pin 2. Następnie, zachowując jeden wiersz przerwy (nóżki włącznika są szeroko rozstawione, co zobaczysz za chwilę), wpinamy styk przewodu. Drugi przewód umieszczamy w wyprowadzeniu napięcia 5 V na płytce Arduino Uno.

RnWiVoE3L9T2P

Zdjęcie przedstawia moduł Arduino z płytką stykową połączone podpiętymi przewodami. Na zdjęciu znajdują się pięć wpiętych rezystorów 220 Ω omega oraz wpięte do płytki stykowej diody LED: zielona, żółta i czerwona symulujące światła dla pojazdów, następnie dalej zielona i czerwona symulujące światła dla pieszych. Przewodami połączono piny z płytką stykową. Podłączono zasilanie do tej samej kolumny, do której jest podpięty pin 2. Następnie, odstępnie jednego wiersza, wpięto styk przewodu. Drugi przewód umieszczono w wyprowadzeniu napięcia 5 V na płytce Arduino Uno.

9. Wpinamy włącznik chwilowy pionowo: powinien się on znaleźć na środku płytki. W poziomie natomiast nóżki powinny być w tych samych wierszach, w których podłączono wcześniej przewody.

RGM6mgA8F53Z2

Na zdjęciu przedstawiono płytkę stykową, do której podpięte są przewody, rezystory oraz diody LED. Wpięto włącznik chwilowy pionowo na środku płytki. Nóżki są wpięte w tych samych wierszach, w których podłączono wcześniej przewody.

10. Podłączamy rezystor 10 kΩomega do masy, wpinając go w tym samym wierszu, w którym znajduje się przycisk RESET. Rezystor ten służy do utrzymania na pinie numer 2 stanu niskiego. Bez tego połączenia na pinie 2. mogłoby pojawić się przypadkowe napięcie. W rezultacie bez wciskania przycisku zostałaby wykonana sekwencja poleceń odpowiadająca za włączenie zielonego światła dla pieszych.

RbY0T9cOnOeQU

Zdjęcie przedstawia płytkę stykową z podpiętymi przewodami, rezystorami oraz diodami LED i włącznikiem. Podłączono także rezystor 10 kΩ omega do masy, wpinając go w tym samym wierszu, w którym znajduje się przycisk RESET.

Programowanie układu

Układ jest gotowy. Pozostaje go zaprogramować. Możemy podłączyć płytkę Arduino do komputera. Na każdym etapie programowania będziemy bowiem sprawdzać, czy poszczególne elementy sygnalizacji działają poprawnie.

Uruchamiamy aplikację Arduino IDE. Pojawia się nowy szkic, w którym są wpisane domyślne funkcje, czyli setup() oraz loop(). Za chwilę będziemy je modyfikować.

Wcześniej spójrz jednak na nazwę pliku. Domyślnie składa się ona z liczb oznaczających dzień i miesiąc oraz z litery. Pierwszy szkic w danym dniu oznaczany jest literą A, każdy kolejny – następnymi literami. Zmień jednak nazwę na taką, która będzie informowała o zawartości szkicu. W tym celu wydaj polecenie Plik | Zapisz jako i podaj nazwę szkicu (na przykład „sygnalizator”). Możesz zapisać plik w folderze domyślnym lub wybrać inny. My zostawiliśmy ten, który zasugerowała aplikacja.

1. Wszystkie elementy szkicu warto opatrywać komentarzami. Pisząc program zaczynamy od informacji, że poniżej zadeklarujemy zmienne. Komentarz umieszczamy wewnątrz sekwencji znaków „/*” oraz „*/” lub po dwóch ukośnikach //, w przypadku gdy komentarz jest jednowierszowy. Zmiennymi będą wszystkie piny, do których zostaną podpięte diody oraz włącznik chwilowy. Numery pinów to liczby całkowite, więc zastosujemy zmienne typu byte lub int. Aby z kodu jasno wynikało, które piny odpowiadają za świecenie sygnalizatora dla pojazdów, a które dla przechodniów, w nazwach zmiennych wpisujemy na przykład ciągi „auta” i „ludzie”:

/* deklaracja zmiennych */
int autaZielonaPin = 10;
int autaZoltaPin = 9;
int autaCzerwonaPin = 8;
int ludzieZielonaPin = 7;
int ludzieCzerwonaPin = 6;
int przycisk = 2;

2. W funkcji setup() należy określić, które piny mają być wejściami, a które wyjściami. W przypadku sygnalizatorów wszystkie piny, do których podłączono diody, będą pinami wyjściowymi (OUTPUT). Natomiast wyłącznik będzie wykonywał określone zadanie – jego naciśnięcie spowoduje wprowadzenie danych do systemu sygnalizacji – i wpływał na działanie diod. Pin przycisku jest zatem pinem wejściowym (INPUT):

void setup() {
	/* ustawienie wejść i wyjść */
	pinMode(autaZielonaPin, OUTPUT);
	pinMode(autaZoltaPin, OUTPUT);
	pinMode(autaCzerwonaPin, OUTPUT);
	pinMode(ludzieZielonaPin, OUTPUT);
	pinMode(ludzieCzerwonaPin, OUTPUT);
	pinMode (przycisk, INPUT);
}

3. W ciele funkcji loop() ustalamy, jak mają się zachowywać diody. Początkowo powinny być włączone: zielone światło dla pojazdów oraz czerwone dla pieszych. Pozostałe diody należy wyłączyć. Dwa pierwsze piny mają mieć zatem ustawiony wysoki stan napięcia (HIGH), a kolejne – stan niski (LOW):

void loop() {
	/* początkowe stany napięcia na pinach,do których podłączone są diody */
	digitalWrite(autaZielonaPin, HIGH);
	digitalWrite(autaZoltaPin, LOW);
	digitalWrite(autaCzerwonaPin, LOW);
	digitalWrite(ludzieZielonaPin, LOW);
	digitalWrite(ludzieCzerwonaPin, HIGH);
}

4. Weryfikujemy poprawność szkicu i przesyłamy go do płytki Arduino.

RGEUlAs12Fye2

Zdjęcie przedstawia płytkę stykową z podpiętymi przewodami, rezystorami oraz diodami LED i włącznikiem. Dioda zielona dla pojazdów oraz dioda czerwona dla pieszych świecą równocześnie.

Pieszy powinien nacisnąć przycisk w celu wymuszenia zmiany świateł. Aby sprawdzić, czy przycisk został naciśnięty zastosujemy instrukcję warunkową if.

if (wyrażenie logiczne) {
	// instrukcja wykonywana jeśli wyrażenie jest prawdziwe 
} else { 
	// instrukcja wykonywana jeśli wyrażenie nie jest prawdziwe
}

W przypadku sygnalizatora będziemy sprawdzać, czy włącznik chwilowy jest naciśnięty. Jeżeli tak, to światła powinny się zmieniać. W przeciwnym razie nadal powinno palić się światło zielone dla pojazdów i czerwone dla przechodniów.

5. Wewnątrz funkcji loop(), za stanami pinów, które określiliśmy wcześniej, wstawiamy instrukcję warunkową if. Na razie nie będzie ona działać, ponieważ brakuje informacji, jakie operacje mają zostać wykonane. Dotychczas ustalaliśmy stany pinów korzystając z funkcji digitalWrite(). Teraz sytuacja się zmienia – musimy odczytać stan pinu, do którego podłączony jest włącznik. Zastosujemy funkcję digitalRead():

/* sprawdzenie stanu włącznika */
if (digitalRead(przycisk) == HIGH) {
	/* zmiana koloru świateł */
} else {
	/* światła bez zmian */
}

W wyrażeniu logicznym pojawia się podwójny znak równości (==). Nie jest to błąd. Podając pojedynczy znak równości przypisujemy zmiennej określoną wartość. Tak jest na samym początku szkicu, kiedy poszczególnym zmiennym przypisywaliśmy numery pinów. Natomiast podwójny znak równości służy do porównania wartości. Instrukcję należy zatem rozumieć w następujący sposób: jeśli odczytany stan pinu, na którym znajduje się włącznik, jest wysoki, to…

6. Po naciśnięciu przycisku światło zielone dla pojazdów ma zostać wyłączone (niski stan napięcia); powinno zapalić się za to światło żółte (wysoki stan napięcia). Światło powinno być ciągłe – zatem za pomocą argumentu funkcji delay() określamy, jak długo dioda  ma się świecić. Przyjmijmy, że będzie to pięć sekund. Czas ten oczywiście wyrażamy w milisekundach.

Weryfikujemy poprawność kodu, przesyłamy go ponownie do płytki Arduino i kiedy światła będą włączone, naciskamy przycisk. Powinna się zapalić żółta dioda, a zielona zgasnąć. Po pięciu sekundach układ powróci do stanu początkowego.

/* sprawdzenie stanu włącznika */
if (digitalRead(przycisk) == HIGH) {
	/*zmiana koloru świateł */
	digitalWrite(autaZielonaPin, LOW);
	digitalWrite(autaZoltaPin, HIGH);
	delay(5000);
}

7. W sygnalizatorze dla pojazdów dioda żółta powinna się następnie wyłączyć; włączyć ma się z kolei dioda czerwona. Natomiast w sygnalizacji dla pieszych musi włączyć się dioda zielona (czerwona ma zgasnąć). Załóżmy, że damy pieszym sześć sekund na przejście przez pasy:

digitalWrite(autaZoltaPin, LOW);
digitalWrite(autaCzerwonaPin, HIGH);
digitalWrite(ludzieCzerwonaPin, LOW);
digitalWrite(ludzieZielonaPin, HIGH);
delay(6000);

Jeżeli zostawimy szkic w takim stanie, to piesi na zielonym świetle będą musieli przebiegać przez ulicę. Zmiana sygnalizacji (powrót do sytuacji początkowej, czyli zatrzymanie pieszych i otwarcie drogi dla pojazdów) nastąpi bowiem nagle. Czerwone światło dla pieszych pojawi  się po sześciu sekundach bez jakiegokolwiek ostrzeżenia.  Musimy uprzedzić przechodniów, że światło zaraz się zmieni na czerwone. Zielone światło powinno więc zacząć migać.

Załóżmy, że światło ma się wyłączyć i włączyć pięć razy. Moglibyśmy teraz wpisać odpowiednie instrukcje, powtarzając je właśnie pięciokrotnie. W tak małym projekcie nie jest to problemem. Ale co zrobić gdy instrukcję trzeba powtórzyć sto razy? Istnieje proste rozwiązanie tego problemu. Jest nim pętla for.

for (licznik = 1; licznik <= n; licznik=licznik + 1) {
	// powtarzany blok instrukcji
}

Zobaczmy, jak będzie to wyglądało w przypadku sygnalizatora.

8. Zacznijmy od deklaracji licznika:

/* deklaracja zmiennych */
int autaZielonaPin = 12;
int autaZoltaPin = 10;
int autaCzerwonaPin = 8;
int ludzieZielonaPin = 7;
int ludzieCzerwonaPin = 6;
int przycisk = 2;
int licznik;

9. Poniżej poprzednich instrukcji wprowadzamy pętlę for():

for (licznik = 0; licznik < 5; licznik = licznik + 1) {
	digitalWrite(ludzieZielonaPin, LOW);
	delay(250);
	digitalWrite(ludzieZielonaPin, HIGH);
	delay(250);
}

10. W kolejnym etapie światło dla przechodniów zmienia się z zielonego (napięcie ma być niskie) na czerwone (napięcie ma być wysokie). Po tej zmianie dajemy sygnał kierowcom, żeby przygotowali się do jazdy. Taka informacja to jednoczesne włączenie światła czerwonego i żółtego. Niech diody o tych barwach świecą na przykład przez dwie sekundy. Pamiętaj, że te instrukcje należy wpisać poniżej pętli for, a nie w jej wnętrzu.

Zapisujemy szkic ([Ctrl]+[S]), weryfikujemy jego poprawność, przesyłamy do płytki Arduino i sprawdzamy, czy sygnalizacja działa.

digitalWrite(ludzieZielonaPin, LOW);
digitalWrite(autaCzerwonaPin, HIGH);
digitalWrite(autaZoltaPin, HIGH);
digitalWrite(ludzieCzerwonaPin, HIGH);
delay(2000);

11. W zasadzie na tym moglibyśmy poprzestać. Został nam jednak jeszcze „przeciwny wypadek”, czyli słowo kluczowe else w instrukcji warunkowej. Czy musimy uzupełniać szkic? W tym szczególnym przypadku nie. Możemy usunąć sekcję else{}. Jeśli chcemy jednak postępować zgodnie z zasadami sztuki, powinniśmy dopisać do programu pewne instrukcje.

Dla sygnalizatorów trzeba określić stan pinów przy założeniu, że włącznik chwilowy nie został naciśnięty, czyli jego napięcie jest niskie. Te stany będą identyczne z wprowadzonymi na samym początku pętli loop():

else {
	/* światła bez zmian */
	digitalWrite(autaZielonaPin, HIGH);
	digitalWrite(autaZoltaPin, LOW);
	digitalWrite(autaCzerwonaPin, LOW);
	digitalWrite(ludzieZielonaPin, LOW);
	digitalWrite(ludzieCzerwonaPin, HIGH);
}

Program jest gotowy, system sygnalizacji działa bezbłędnie, a ty wiesz coraz więcej. Nie zamykaj jednak jeszcze szkicu. Zauważ, że wszystkie instrukcje pisaliśmy rozpoczynając od lewej strony ekranu. Czy tak napisany szkic wygląda przejrzyście? Zdecydowanie nie.

Dlaczego zatem nie formatowaliśmyformatowanie koduformatowaliśmy od razu kodu? Otóż dlatego, aby pokazać, jak program formatuje go sam. Wystarczy, że wciśniesz kombinację klawiszy Ctrl+T lub wybierzesz w menu Narzędzia polecenie Automatyczny format.

Kod od razu wygląda lepiej. Pojawiły się wcięcia i widać już, gdzie zaczynają się i kończą deklaracje, funkcje i pętle. Oczywiście z automatycznego formatowania możesz skorzystać na każdym etapie programowania. Warto jednak wyrobić w sobie nawyk przesuwania na prawo wszystkiego, co rozpoczyna się nawiasem klamrowym. W Arduino zazwyczaj stosuje się przesunięcie za pomocą dwóch spacji, ale można też używać do tego klawisza Tab.

Poniżej znajduje się cały kod programu sformatowany w sposób automatyczny oraz film pokazujący działanie szkicu.

/* deklaracja zmiennych */
int autaZielonaPin = 10;
int autaZoltaPin = 9;
int autaCzerwonaPin = 8;
int ludzieZielonaPin = 7;
int ludzieCzerwonaPin = 6;
int przycisk = 2;
int licznik;

void setup() {
	/* ustawienie wejść i wyjść */
	pinMode(autaZielonaPin, OUTPUT);
	pinMode(autaZoltaPin, OUTPUT);
	pinMode(autaCzerwonaPin, OUTPUT);
	pinMode(ludzieZielonaPin, OUTPUT);
	pinMode(ludzieCzerwonaPin, OUTPUT);
	pinMode(przycisk, INPUT);
}

void loop() {
	/* początkowe stany napięcia na pinach,do których podłączone są diody */
	digitalWrite(autaZielonaPin, HIGH);
	digitalWrite(autaZoltaPin, LOW);
	digitalWrite(autaCzerwonaPin, LOW);
	digitalWrite(ludzieZielonaPin, LOW);
	digitalWrite(ludzieCzerwonaPin, HIGH);
  
	/* sprawdzenie stanu włącznika */
	if (digitalRead(przycisk) == HIGH) {
		/* zmiana koloru świateł */
		digitalWrite(autaZielonaPin, LOW);
		digitalWrite(autaZoltaPin, HIGH);
		delay(5000);
		digitalWrite(autaZoltaPin, LOW);
		digitalWrite(autaCzerwonaPin, HIGH);
		digitalWrite(ludzieCzerwonaPin, LOW);
		digitalWrite(ludzieZielonaPin, HIGH);
		delay(6000);

		for (licznik = 0; licznik < 5; licznik = licznik + 1) {
			digitalWrite(ludzieZielonaPin, LOW);
			delay(250);
			digitalWrite(ludzieZielonaPin, HIGH);
			delay(250);
		}
    
		digitalWrite(ludzieZielonaPin, LOW);
		digitalWrite(autaCzerwonaPin, HIGH);
		digitalWrite(autaZoltaPin, HIGH);
		digitalWrite(ludzieCzerwonaPin, HIGH);
		delay(2000);
	} else {
		/* światła bez zmian */
		digitalWrite(autaZielonaPin, HIGH);
		digitalWrite(autaZoltaPin, LOW);
		digitalWrite(autaCzerwonaPin, LOW);
		digitalWrite(ludzieZielonaPin, LOW);
		digitalWrite(ludzieCzerwonaPin, HIGH);
	}
}

Ryf10yFXwS6gt

Film nawiązujący do treści lekcji dotyczącej świateł drogowych. Na filmie przedstawiono płytkę stykową z podpiętymi przewodami, rezystorami oraz diodami LED i włącznikiem. Diody ustawione są następująco od lewej diody dla pieszych: czerwona, zielona, odstęp i dalej diody dla pojazdów, czerwona, żółta i zielona. Najpierw równocześnie świecą dioda czerwona dla pieszych oraz zielona dla pojazdów. Następnie osoba klika włącznik, co powoduje zaświecenie diody czerwonej dla pieszych i żółtej dla pojazdów. Po kilku sekundach następuje kolejna zmiana, w wyniku której świeci się dioda zielona dla pieszych oraz czerwona dla pojazdów. Po następnych kilku sekundach dioda zielona dla pieszych zaczyna migać, a po chwili przez około dwie sekundy świecą się diody: czerwona dla pieszych, czerwona i żółta dla pojazdów. Następnie wracamy do punktu wyjścia: świecą się dwie diody: czerwona dla pieszych i zielona dla pojazdów.

Film nawiązujący do treści lekcji dotyczącej świateł drogowych. Na filmie przedstawiono płytkę stykową z podpiętymi przewodami, rezystorami oraz diodami LED i włącznikiem. Diody ustawione są następująco od lewej diody dla pieszych: czerwona, zielona, odstęp i dalej diody dla pojazdów, czerwona, żółta i zielona. Najpierw równocześnie świecą dioda czerwona dla pieszych oraz zielona dla pojazdów. Następnie osoba klika włącznik, co powoduje zaświecenie diody czerwonej dla pieszych i żółtej dla pojazdów. Po kilku sekundach następuje kolejna zmiana, w wyniku której świeci się dioda zielona dla pieszych oraz czerwona dla pojazdów. Po następnych kilku sekundach dioda zielona dla pieszych zaczyna migać, a po chwili przez około dwie sekundy świecą się diody: czerwona dla pieszych, czerwona i żółta dla pojazdów. Następnie wracamy do punktu wyjścia: świecą się dwie diody: czerwona dla pieszych i zielona dla pojazdów.

Film dostępny pod adresem /preview/resource/Ryf10yFXwS6gt

Film nawiązujący do treści lekcji dotyczącej świateł drogowych. Na filmie przedstawiono płytkę stykową z podpiętymi przewodami, rezystorami oraz diodami LED i włącznikiem. Diody ustawione są następująco od lewej diody dla pieszych: czerwona, zielona, odstęp i dalej diody dla pojazdów, czerwona, żółta i zielona. Najpierw równocześnie świecą dioda czerwona dla pieszych oraz zielona dla pojazdów. Następnie osoba klika włącznik, co powoduje zaświecenie diody czerwonej dla pieszych i żółtej dla pojazdów. Po kilku sekundach następuje kolejna zmiana, w wyniku której świeci się dioda zielona dla pieszych oraz czerwona dla pojazdów. Po następnych kilku sekundach dioda zielona dla pieszych zaczyna migać, a po chwili przez około dwie sekundy świecą się diody: czerwona dla pieszych, czerwona i żółta dla pojazdów. Następnie wracamy do punktu wyjścia: świecą się dwie diody: czerwona dla pieszych i zielona dla pojazdów.